Feedly APIを使用してみる（４）

' 全取得、カテゴリ一覧、Feed一覧により、データを取るコマンドを変更しています。
If bType = 1 Then
    ' 全件取得コマンド（category/global.allで、カテゴリに登録されている全ての記事を取得します）
    setCmd = "user/" & rssPro.id & "/category/global.all"
ElseIf bType = 2 Then
    ' カテゴリ指定
    If lstCate.SelectedIndex < 0 Then
        MsgBox("カテゴリが選択されていません！")
        Exit Sub
    End If
    lstIdx = lstCate.SelectedIndex
    If cateList(lstIdx).cID = "NoID" Then
        MsgBox("カテゴリなしなので、フィードで実行して下さい！")
        Exit Sub
    End If
    ' カテゴリの場合は、カテゴリIDを指定するだけです。
    setCmd = cateList(lstIdx).cID
ElseIf bType = 3 Then
    ' Ｆｅｅｄ指定
    If lstFeed.SelectedIndex < 0 Then
        MsgBox("Ｆｅｅｄが選択されていません！")
        Exit Sub
    End If
    lstIdx = lstFeed.SelectedIndex
    ' フィードの場合は、フィードIDを指定するだけです。
    setCmd = feedList(lstIdx).fID
End If

' ストリームエントリを取る。
Try
    ' 取得種別（未読のみのチェックボックスにチェックが入っている場合は未読記事のみを取得します）
    If chkUnRead.Checked = True Then
        ' 未既読のみ
        entriVal = RSSharp.Feedly.ApiCalls.Streams.get_entries_in_stream(pAccessTkn, setCmd, 1000,, True)
    Else
        ' 全て
        entriVal = RSSharp.Feedly.ApiCalls.Streams.get_entries_in_stream(pAccessTkn, setCmd, 1000,,,)
    End If

    ' entriVal（型：RSSharp.Feedly.ApiCalls.Streams.entries_list）に記事が格納されます。

Catch ex As Exception
End Try

' ０件の場合
If entriVal.items Is Nothing OrElse entriVal.items.Count = 0 Then
    MsgBox("データがありません！")
    Exit Sub
End If

lblEntryCnt.Text = entriVal.items.Count.ToString & "件"

' 表示エリアに表示する。
Dim setData As String
Dim setRead As String
Dim setTime As String
For i = 0 To entriVal.items.Count - 1

    ' 既読、未読（unreadで既読か未読かを判定できます）
    If entriVal.items(i).unread = True Then
        setRead = "【未読】"
    Else
        setRead = "【既読】"
    End If

    ' 投稿時間（crawledで記事の投稿時間を取得できます。タイムスタンプのため時間へ変換）
    setTime="【" & DateTimeOffset.FromUnixTimeMilliseconds(
entriVal.items(i).crawled).ToLocalTime.ToString.Substring(0, 19) & "】"

    ' セットデータ（origin.title＝フィードタイトル　title＝記事タイトル）
    setData = setRead & setTime & "【" & entriVal.items(i).origin.title & "】" & entriVal.items(i).title

    lstEntry.Items.Add(setData)

Next

' ①記事一覧で取得した'entriVal（型：RSSharp.Feedly.ApiCalls.Streams.entries_list）より詳細な情報を表示

' カテゴリ（categories）よりカテゴリ情報を取得
' 記事には複数のカテゴリが登録可能なのでcategoriesは登録されている全てのカテゴリが含まれます。
' サンプルプログラムでは1件目のみ表示してます。
If entriVal.items(lstIdx).categories Is Nothing = False Then
    lblCate.Text = entriVal.items(lstIdx).categories(0).label
End If

' コンテンツデータ（summary.contentでコンテンツデータ取得）
If entriVal.items(lstIdx).summary Is Nothing = False Then
    contentData = entriVal.items(lstIdx).summary.content
Else
    contentData = "[no content]"
End If
txtContent.Text = contentData

' リンク（alternate(0).hrefでサイトＵＲＬを取得）
If entriVal.items(lstIdx).alternate(0).href Is Nothing = False Then
    lblLink.Text = entriVal.items(lstIdx).alternate(0).href
End If

' キーワード（keywordsで登録されている全てのキーワードを取得できます）
If entriVal.items(lstIdx).keywords Is Nothing = False Then
    For i = 0 To entriVal.items(lstIdx).keywords.Count - 1
        If i = 0 Then
            keyData = "【" & entriVal.items(lstIdx).keywords(i) & "】"
        Else
            keyData = keyData & "【" & entriVal.items(lstIdx).keywords(i) & "】"
        End If
    Next
    txtKeyword.Text = keyData
End If